3.2. Wat is de arbeidsintensiteit PNIL?

Concepten

• Grootboekpost
• Grootboekrubriek

Relaties

• deel van
• deel van

Eigenschappen

• heeft datum
• heeftGeldBedrag

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.2
2# Parameters: ?jaar
3# Ontologie: versie 3.0.0 of nieuwer
4
5PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
6PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
7PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
8
9SELECT ?Kental (?Waarde AS ?Arbeidsintensiteit)
10WHERE {
11  {
12    SELECT
13      (
14        IF(
15          BOUND(?p_totaal) && (?p_totaal != 0),
16          (xsd:decimal(?q_bedragen) / xsd:decimal(?p_totaal)),
17          "Ongedefinieerd"
18        ) AS ?aipnil
19      )
20    WHERE {
21      {
22        SELECT ((COALESCE(?p_prismant,0) + COALESCE(?p_rgs,0)) AS ?p_totaal) ((COALESCE(?q_prismant,0) + COALESCE(?q_rgs,0)) AS ?q_bedragen)
23        WHERE {
24
25          {
26            SELECT
27              (SUM(?p_bedrag_prismant) AS ?p_prismant)
28              (SUM(?q_bedrag_prismant) AS ?q_prismant)
29            WHERE {
30              #BIND(2024 AS ?jaar)
31              BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
32              BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode)
33
34              {
35                SELECT DISTINCT ?rubriek WHERE {
36                  ?rubriek a onz-fin:Grootboekrubriek .
37                  FILTER(STRSTARTS(STR(?rubriek), STR(onz-fin:)))
38                  FILTER(REGEX(STRAFTER(STR(?rubriek), STR(onz-fin:)), "^[0-9]{6}$"))
39                }
40              }
41
42              BIND(STRAFTER(STR(?rubriek), STR(onz-fin:)) AS ?rubriekCode)
43
44              ?grootboek_post a onz-fin:Grootboekpost ;
45                              onz-g:partOf ?rubriek ;
46                              onz-g:hasDate ?datum ;
47                              onz-fin:heeftGeldBedrag ?geld_bedrag .
48
49              FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
50
51              BIND(
52                IF(
53                  STRSTARTS(?rubriekCode, "8") ||
54                  STRSTARTS(?rubriekCode, "919") ||
55                  STRSTARTS(?rubriekCode, "920") ||
56                  STRSTARTS(?rubriekCode, "930"),
57                  ?geld_bedrag, 0
58                ) AS ?p_bedrag_prismant
59              )
60
61              BIND(
62                IF(
63                  STRSTARTS(?rubriekCode, "417")  ||
64                  STRSTARTS(?rubriekCode, "418"),
65                  ?geld_bedrag, 0
66                ) AS ?q_bedrag_prismant
67              )
68            }
69          }
70
71          {
72            SELECT
73              (SUM(?p_bedrag_rgs) AS ?p_rgs)
74              (SUM(?q_bedrag_rgs) AS ?q_rgs)
75            WHERE {
76              #BIND(2024 AS ?jaar)
77              BIND(STRDT(CONCAT(STR(?jaar),"-01-01"),xsd:date) AS ?startperiode)
78              BIND(STRDT(CONCAT(STR(?jaar),"-12-31"),xsd:date) AS ?eindperiode)
79
80              VALUES (?rubriek ?soort) {
81                (onz-fin:WOmz "P")
82                (onz-fin:WRev "P")
83                (onz-fin:WRvi "P")
84                (onz-fin:WRgr "P")
85                (onz-fin:WWvv "P")
86                (onz-fin:WNoa "P")
87                (onz-fin:WLbe "P")
88                (onz-fin:WBat "P")
89                (onz-fin:WWiv "P")
90                (onz-fin:WOvb "P")
91                (onz-fin:WKprKuw      "Q")
92                (onz-fin:WKprKvp      "Q")
93                (onz-fin:WBedOvpUik   "Q")
94                (onz-fin:WBedOvpUit   "Q")
95                (onz-fin:WBedOvpMaf   "Q")
96                (onz-fin:WBedOvpZzp   "Q")
97                (onz-fin:WBedOvpPay   "Q")
98                (onz-fin:WBedOvpOip   "Q")
99              }
100
101              ?grootboek_post a onz-fin:Grootboekpost ;
102                              onz-g:partOf* ?rubriek ;
103                              onz-g:hasDate ?datum ;
104                              onz-fin:heeftGeldBedrag ?geld_bedrag .
105
106              FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
107
108              BIND(IF(?soort = "P", ?geld_bedrag, 0) AS ?p_bedrag_rgs)
109              BIND(IF(?soort = "Q", ?geld_bedrag, 0) AS ?q_bedrag_rgs)
110            }
111          }
112        }
113      }
114    }
115  }
116
117  VALUES ?Kental {
118    "Arbeidsintensiteit PNIL"
119    "Arbeidsintensiteit PNIL (%)"
120  }
121
122  BIND(
123    IF(
124      DATATYPE(?aipnil) = xsd:string,
125      "Ongedefinieerd"^^xsd:string,
126      IF(
127        ?Kental = "Arbeidsintensiteit PNIL",
128        ROUND(?aipnil * 100) / 100,
129        ROUND((?aipnil * 100) * 100) / 100
130      )
131    ) AS ?Waarde
132  )
133}
134ORDER BY ?Kental
135